要写个电脑配置单   
不想一台台的看
给我发一个撒


问题已经搞定了。。  通过开机通道 运行下边的VBS 脚本

免费内容:

   
  Dim objWMIService
  Set objWMIService = Getobject("winmgmts:\\.\root\cimv2")
  Dim objOSInfos, objOSInfo, OSInfo, ComputerName, OSVer
  Set objOSInfos = objWMIService.execQuery("Select * From win32_operatingsystem")
  For Each objOSInfo In objOSInfos
    OSInfo = objOSInfo.CSName & ","
    ComputerName = objOSInfo.CSName
    OSVer = objOSInfo.Version
    OSInfo = OSInfo & objOSInfo.Caption & " " & objOSInfo.CSDVersion & ","
    OSInfo  = OSInfo & Mid(CStr(objOSInfo.InstallDate),1,4) & "-" & _
              Mid(CStr(objOSInfo.InstallDate),5,2) & "-" & _
              Mid(CStr(objOSInfo.InstallDate),7,2) & ","
  Next
  
  Dim objBoards, objBoard, BoardInfo
  Set objBoards = objWMIService.execQuery("Select * From Win32_BaseBoard")
  For each objBoard In objBoards
    BoardInfo = Trim(objBoard.Product) & ","
    BoardInfo = BoardInfo & Trim(objBoard.Manufacturer) & ","
  Next
  
  Dim objCPUs, objCPU, CPUInfo
  Set objCPUs = objWMIService.execQuery("Select * From win32_processor")
  For each objCPU In objCPUs
    CPUInfo = Trim(objCPU.Name) & ","
    CPUInfo = CPUInfo & objCPU.ExtClock & ","
    CPUInfo = CPUInfo & objCPU.L2CacheSize & ","
    CPUInfo = CPUInfo & objCPU.SocketDesignation & ","
  Next
  
  Dim objMemorys, objMemory, MemoryInfo
  Set objMemorys = objWMIService.execQuery("Select * From Win32_PhysicalMemory")
  Redim arrMemory(1)
  For Each objMemory In objMemorys
    arrMemory(0) = arrMemory(0) + objMemory.capacity/1048576
    arrMemory(1) = arrMemory(1) & objMemory.Speed & "/" & objMemory.DeviceLocator & " "
  Next
  MemoryInfo = objMemorys.Count  & "条，共" & arrMemory(0) & "M," & arrMemory(1) & ","
  
  Dim objDisks, objDisk, DiskInfo
  Set objDisks = objWMIService.execQuery("Select * From win32_diskdrive")
  For Each objDisk In objDisks
    DiskInfo = Trim(objDisk.Model) & ","
    Exit For
  Next
  
  Dim objVideos, objVideo, VideoInfo
  Set objVideos = objWMIService.execQuery("Select * From win32_videocontroller")
  For Each objVideo In objVideos
    If Not IsNull(objVideo.VideoModeDescription) Then
        VideoInfo = Trim(objVideo.Description)
        VideoInfo = VideoInfo & "(" & objVideo.AdapterRAM/1048576 & "M),"
    End If
  Next
  
  Dim objNetworks, objNetwork, objNetworks_2, objNetwork_2, NetWorkInfo
  NetWorkInfo = ""
  Set objNetworks = objWMIService.execQuery("Select * From Win32_NetworkAdapter")
  Set objNetworks_2 = objWMIService.execQuery("Select * From Win32_NetworkAdapterConfiguration")
  For Each objNetwork In objNetworks
    If objNetwork.Manufacturer <> "Microsoft" And Not Isnull(objNetwork.MACAddress) Then
      For Each objNetwork_2 In objNetworks_2
        If objNetwork_2.Index = objNetwork.Index Then
          NetWorkInfo = objNetwork.Description & "," & objNetwork_2.IPAddress(0) & _
                        Space(17-Len(objNetwork_2.IPAddress(0))) & _
                        Replace(objNetwork_2.MACAddress,":","-")
          Exit For
        End If
      Next
      If NetWorkInfo <> "" Then Exit For
    End If
  Next
  
  '输出信息到文件
  Dim FSO, OutFile
  Set FSO = WScript.Createobject("Scripting.Filesystemobject")
  SerVerPath = "\\computer\硬件信息$\" '信息文件保存远程路径
  Set OutFile = FSO.CreateTextFile(SerVerPath & "\" & ComputerName & ".txt",True)
  OutFile.Writeline OSInfo & BoardInfo & CPUInfo & MemoryInfo & DiskInfo & VideoInfo & NetWorkInfo

[ 本帖最后由 那鬼 于 2008-4-3 14:35 编辑 ]

只有单机的

有时有，要在对方机器上装客户端的！

哎 用了个懒办法弄好了。。用开机批处理 通过VBS脚本读取注册表信息。。

厲害，牛牛不會滴說